// import Cosmetics/PetBoo
//-MAX-WIDTH-MARKER-----------------------------

func standby()
  >`0,0,Loc = @loc@|@loc.id@
  >`0,1,Foe = @foe.id@:@foe.state@,@foe.time@
  >`0,2,@foe.debuffs.string@
  >`0,3,@foe.buffs.string@
  ?pickup.distance < 10
    equipL star
    equipR compound shield *10
  :?target = waypoint | foe.distance > 22
    ?hp < maxhp
      equipL ouroboros
      equipR compound shield *10
    :
      equipL triskelion
      equipR compound shield *10
  ?hp < 10
    activate potion

func eq_ranged()
  equipL fire wand *10
  equipR crossbow *10

func eq_dashing()
  equipL poison sword *10
  equipR dashing shield

func eq_fire_ranged()
  equipL fire wand
  equipR crossbow

func eq_melee()
  equipL poison sword *10
  equipR shield *10
  //equip blade of the fallen god

func eq_dbl_melee()
  equipL poison sword *10
  equipR vigor sword *10

func eq_vigor_melee()
  equipL vigor sword *10
  equipR compound shield *10

func eq_magic_ranged()
  //equipL fire wand *10
  equipL vigor wand *9
  equipR aether wand *10

?loc = rocky_plateau
  ?foe
    ?foe.distance >= 8
      eq_dashing()
    :
      eq_dbl_melee()
  standby()

?loc = deadwood
  ?foe.count > 9
    ^& item.GetCooldown("blade") <= 0
      equip blade
      activate R
  :?foe = mosquito
    ?foe.distance >= 5
      eq_ranged()
    :
      eq_melee()
  :?foe = scarab
    eq_melee()
  :?foe = boss | foe = poena
    ?foe.distance >= 8
      eq_dashing()
    :
      eq_dbl_melee()
  standby()
//  ?harvest.distance < 10
//    equip hatchet
//    ?harvest.distance <= 4
//    ^& item.GetCooldown("hatchet") <= 0
//      activate R

:?loc = caves
  ?foe ! boss
    eq_ranged()
  :?foe = boss
    eq_melee()
  standby()

:?loc = halls
  ?foe ! boss
    ?foe.count > 6
    ^& item.GetCooldown("blade") <= 0
      equip blade
      activate R
    :
      eq_magic_ranged()
  :?foe = boss
    ?foe.distance > 8
      eq_dashing()
    :
      eq_dbl_melee()
  standby()

:?loc = forest
  ?foe ! boss
    ?foe.count > 5
    ^& item.GetCooldown("blade") <= 0
      equip blade
      activate R
    :
      eq_magic_ranged()
  :?foe = boss
    ?foe.distance > 8
      eq_dashing()
    :
      eq_dbl_melee()
  standby()

:?loc = ridge
  ?foe
    eq_fire_ranged()
  standby()

:
  ?foe
    eq_magic_ranged()
  standby()